Computation of the Wodzicki-Chern-Simons form in local coordinates.
Computations for (S^1)actions on  (S^3): The Hopf Action.
(Last update:November 26,2008.)

(* We define a local system of coordinates for  M = (S^3) and compute the Christoffel symbols and curvature. We use spherical coordinates on (S^(3 ))to compute the zeroth and -1 order symbols for the connection form and the zeroth and -1 order symbol for the curvature form on the loop space LM. Then we compute the Wodzicki-Chern-Simons form. Each (S^1) action on (S^3) determines a homology class in LM. We compute the value of the WCS form on these classes for the n-fold iteration of the Hopf action, and show that each of these iterates are different (i.e. determine nonhomologous classes in  (Subscript[H, 3])(LM) ) for n = 0, 1, 2.  We certainly expect that the iterates are different for all values of n.*)

Table of contents:  
  (1) Preliminaries -- the main procedures to compute Christoffel symbols,
	    curvature, and symbols for the connection and curvature forms on loop space.  
(2) Evaluation of the Wodzicki-Chern-Simons form on a cycle inL((S^(3 )))associated to the Hopf action.
            (2.1) Curvature term contribution: the contribution from  (Subscript[σ, -1])(Ω)\wedge (Subscript[σ, 0])(ω)
	       (2.2) Curvature term contribution:  Contribution from the term (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(Ω)
	       (2.3) Connection term contribution:  Contribution from the term (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(ω) \wedge (Subscript[σ, 0])(ω)
	  (3) Conclusions

1. Preliminaries

SetDirectory["C:\Documents and Settings\\fatorres\\Desktop\\FABIAN\\Mathematica"];

SetDirectory["research/fabian/07/notebooks"];

Spherical Coordinates

Spherical Coordinates: Use coordinate system (Phi, Psi, Theta) for (S^3). Recall for (x, y, z, w) in (R^4):
w=Cos[Psi], x= Sin[Psi]*Sin[Phi]*Cos[Theta], y= Sin[Psi]*Sin[Phi]*Sin[Theta], z= Sin[Psi]*Cos[Phi].
(S^3)={(x,y,z,w) \in (R^4): x^2+y^2+z^2+w^2= 1}.

(*Define coordinates Phi, Psi, Theta on (S^3). We use exponential coordinates on (S^3), so Theta\in [0, 2\pi], Phi, Psi \in [0,\pi] sweep out a ball of radius \pi in the tangent space at the north pole of (S^3).  We fix these coordinates independent of the metric we choose on (S^3). The coordinates are valid on (S^3) minus the south pole, which is good enough for integral calculations.*)

Clear[coord,metric,inversemetric,Christoffel,Theta,Phi,Xi,x,X1,X2,X3,X4,A,Con,NumIt];
dimension=3;
coord={Theta,Phi,Psi, tau};
PsiForm={P1si,P2si,P3si,P4si};

XField={X1,X2,X3};
YField={Y1,Y2,Y3};
WField={W1,W2,W3};
ZField={Z1,Z2,Z3};
DotGamma={Dot1,Dot2,Dot3,Dot4};

Define the metric in spherical coordinates on (S^3): the standard metric.

metric={{F[Theta,Phi,Psi,tau],0,0},{0,G[Theta,Phi,Psi,tau],0},{0,0,H[Theta,Phi,Psi,tau]}};

F[Theta_,Phi_,Psi_,x_]:=Sin[Psi]^2*Sin[Phi]^2;
G[Theta_,Phi_,Psi_,x_]:=Sin[Psi]^2;
H[Theta_,Phi_,Psi_,x_]:=1;

metric//MatrixForm

detmetric=Det[metric];
Sqrtdetmetric=PowerExpand[Sqrt[detmetric]];

(*Computation of the metric inverse.*)

inversemetric=Inverse[metric]

metric=Simplify[metric];
inversemetric=Simplify[inversemetric];

(*Definition of the Christoffel Symbols:Notation:Christoffel[i,j,k]:=\Gamma^i_{j,k}.*)

Christoffel=Christoffel=Table[(1/2)*Sum[(inversemetric[[i,s]])*(D[metric[[s,j]],coord[[k]]]+D[metric[[s,k]],coord[[j]]]-D[metric[[j,k]],coord[[s]]]),{s,1,dimension}],{i,1,dimension},{j,1,dimension},{k,1,dimension}];

listaffine:=Table[{ToString[Γ[i,j,k]],Christoffel[[i,j,k]]},{i,1,dimension},{j,1,dimension},{k,1,dimension}]

TableForm[listaffine,TableSpacing->{1,1}]

(*Definition of the Curvature:Notation:Curvature[i,j,k,l]:=R^i_{jkl}.*)

Curvature=Curvature=Table[D[Christoffel[[i,j,l]],coord[[k]]]-D[Christoffel[[i,j,k]],coord[[l]]]+Sum[Christoffel[[s,j,l]] Christoffel[[i,k,s]]-Christoffel[[s,j,k]] Christoffel[[i,l,s]],{s,1,dimension}],{i,1,dimension},{j,1,dimension},{k,1,dimension},{l,1,dimension}];

ListCurvature:=Table[If[UnsameQ[Curvature[[i,j,k,l]],0],{ToString[R[i,j,k,l]],Curvature[[i,j,k,l]]}],{i,1,dimension},{j,1,dimension},{k,1,dimension},{l,1,dimension}]
TableForm[Partition[DeleteCases[Flatten[ListCurvature],Null],2],TableSpacing->{2,2}]

(*Computation of the covariant derivative for the curvature.Notation CovCurvature[i,j,k,m,p]=R^{m}_{\ ijk;p}*)

CovCurvature=CovCurvature=Table[D[Curvature[[m,i,j,k]],coord[[p]]]+Sum[Curvature[[t,i,j,k]]*Christoffel[[m,p,t]],{t,1,dimension}]-Sum[Curvature[[m,t,j,k]]*Christoffel[[t,p,i]],{t,1,dimension}]-Sum[Curvature[[m,i,t,k]]*Christoffel[[t,p,j]],{t,1,dimension}]-Sum[Curvature[[m,i,j,t]]*Christoffel[[t,p,k]],{t,1,dimension}],{i,1,dimension},{j,1,dimension},{k,1,dimension},{m,1,dimension},{p,1,dimension}];

2.  Evaluation of the Wodzicki-Chern-Simons form on a cycle inL((S^(3 )))associated to the Hopf action.

As explained in the paper, the Hopf action of (S^3)determines a cycle in L((S^3)) which is a pushforward of the fundamental class of (S^3). We evaluate the WCS form on this cycle as an integral over (S^3) and show that this integral is non-zero. This implies that the Hopf action is nontrivial in the sense defined in our paper.
     We compute the WCS form at a typical loop γ(τ) of the Hopf action. In spherical coordinates we obtain a loop γ(τ)∈ (S^3) given by the expression
γ(θ, ϕ, ψ, τ)=(Cos τ Cos θ Sin ϕ Sin ψ - Sin ϕ Sin ψ Sin τ Sin θ, Cos θ Sin ϕ Sin ψ Sin τ + Cos τ Sin ϕ Sin ψ Sin θ,  Cos ϕ Cos τ Sin ψ - Cos ψ Sin τ,  Cos ϕ Cos τ Sin ψ+ Cos ϕ Sin τ). We compute the derivative of γ(τ)  with respect to τ, and express the result in terms of the of the basis for (Subscript[T, γ(τ)])(S^3) given by spherical coordinates. The outcome is stored in the variable (Dot1, Dot2, Dot3).
     We also consider iterates of the Hopf action where we replace γ(τ) by γ(nτ)  for n an integer.  We keep track of n via the variable NumIt.

At this point we define the components of the vectors X, Y, and W on which we will evaluate the CSW form. We also define the components of \dot\gamma(\tau). All these have been computed for the Hopf action.  X, Y, W  are tangent vectors to a loop γ associated to the map h:(S^3) -> L((S^3)) by X = (Subscript[h, * ])(partial(theta)), Y = (SubStar[h])(partial(phi)), Z = (SubStar[h])(partial(psi)), with h the map induced by the Hopf action.

Dot1=NumIt*Cos[NumIt*tau] Sin[Phi] Sin[Psi];
Dot2=NumIt*Cos[Psi] Cos[NumIt*tau] Sin[Phi];
Dot3=NumIt*(-((Cos[Phi])^2) Cos[Psi] Sin[Psi] Sin[NumIt*tau]-Cos[Psi] Sin[Psi] (Cos[NumIt*tau]+((Sin[Phi])^2) Sin[NumIt*tau])+Cos[Phi] (-((Cos[Psi])^2) Cos[NumIt*tau]+((Sin[Psi])^2) Sin[NumIt*tau]));
X1=Cos[NumIt*tau] Sin[Phi] Sin[Psi];X2=-Cos[Phi] Sin[Phi] Sin[Psi] Sin[NumIt*tau];X3=-Cos[Psi] ((Sin[Phi])^2) Sin[Psi] Sin[NumIt*tau];
Y1=Cos[Phi] Sin[Psi] Sin[NumIt*tau];Y2=Cos[NumIt*tau] Sin[Psi];Y3=Cos[NumIt*tau] Sin[Phi] ((Sin[Psi])^2);
W1=Cos[Psi] Sin[Phi] Sin[NumIt*tau];W2=-Sin[Psi] Sin[NumIt*tau];W3=Cos[Psi] Cot[Phi] (-Cos[NumIt*tau]+Sin[NumIt*tau])+Csc[Phi] (Cos[Psi] Cos[NumIt*tau] Cot[Psi]+Sin[Psi] Sin[NumIt*tau]);
Permu={{{X1,X2,X3},{Y1,Y2,Y3},{W1,W2,W3}},{{X1,X2,X3},{W1,W2,W3},{Y1,Y2,Y3}},{{Y1,Y2,Y3},{X1,X2,X3},{W1,W2,W3}},{{Y1,Y2,Y3},{W1,W2,W3},{X1,X2,X3}},{{W1,W2,W3},{X1,X2,X3},{Y1,Y2,Y3}},{{W1,W2,W3},{Y1,Y2,Y3},{X1,X2,X3}}};
SignPermu={1,-1,-1,1,1,-1};

(2.1) Curvature terms contribution: the contribution from  (Subscript[σ, -1])(Ω)\wedge (Subscript[σ, 0])(ω)

Clear[ZeroMinusOneTerm1,ZeroMinusOneTerm2,ZeroMinusOneTerm3]

(*Computation of new terms from expression (A.25) in the paper. The terms multiplying (X^i)(Y^j)\dot (γ^( n)).*)

ZeroMinusOneTerm1[X_,Y_,W_]:= Sum[(D[Christoffel[[a, e,j]],coord[[n]],coord[[i]]]-D[Christoffel[[a, n,j]],coord[[e]],coord[[i]]] -D[Christoffel[[a, e,i]],coord[[n]],coord[[j]]]+D[Christoffel[[a, n,i]],coord[[e]],coord[[j]]]+Sum[metric[[r,e]]*inversemetric[[l,a]]( (4*Con-3)(D[Christoffel[[r, l,j]],coord[[n]],coord[[i]]]-D[Christoffel[[r, l,i]],coord[[n]],coord[[j]]]) +D[Christoffel[[r, n,i]],coord[[l]],coord[[j]]]+D[Christoffel[[r, n,j]],coord[[l]],coord[[i]]]),{l,1,dimension}, {r,1,dimension}])*X[[i]]*Y[[j]]*Christoffel[[e, a,k]]*W[[k]]*DotGamma[[n]],{a,1,dimension},{e,1,dimension},{k,1,dimension},{n,1,dimension},{i,1,dimension},{j,1,dimension}]

(*The terms with the dot derivatives written as covariant expressions.*)

ZeroMinusOneTerm2[X_,Y_,W_]:= Sum[(-4/3*Con*(Curvature[[a,j,i,e]]-Curvature[[a,i,j,e]])+1/3*Curvature[[a,j,i,e]])*Christoffel[[e, a,k]]* (D[X[[i]],coord[[4]]]+ Sum[DotGamma[[t]]*X[[r]]*Christoffel[[i,t,r]],{t,1,dimension},{r,1,dimension}])*Y[[j]]*W[[k]],{a,1,dimension},{e,1,dimension},{k,1,dimension},{l,1,dimension},{i,1,dimension},{j,1,dimension}]

ZeroMinusOneTerm3[X_,Y_,W_]:= Sum[(-4/3*Con*(Curvature[[a,i,j,e]]-Curvature[[a,j,i,e]])+1/3*Curvature[[a,i,j,e]])*Christoffel[[e, a,k]]* (D[Y[[j]],coord[[4]]]+ Sum[DotGamma[[t]]*Y[[r]]*Christoffel[[i,t,r]],{t,1,dimension},{r,1,dimension}])*X[[i]]*W[[k]],{a,1,dimension},{e,1,dimension},{k,1,dimension},{l,1,dimension},{i,1,dimension},{j,1,dimension}]

(*Computation of certain permutations of the fields X,Y,Z; *)

XField={X1,X2,X3};
YField={Y1,Y2,Y3};
WField={W1,W2,W3};
ZField={Z1,Z2,Z3};

Permu=Permutations[{X,Y,W}]

{{X,Y,W},{X,W,Y},{Y,X,W},{Y,W,X},{W,X,Y},{W,Y,X}}

SignPermu=Table[Signature[Permu[[i]]],{i,1,6}]

SignPermu={1,-1,-1,1,1,-1};

SignPermu={1,-1,-1,1,1,-1,-1,1,1,-1,-1,1,1,-1,-1,1,1,-1,-1,1,1,-1,-1,1}

SignPermuTwo=Table[SignPermu[[i]]*Permu[[i]],{i,1,6}]

{{X,Y,W},{-X,-W,-Y},{-Y,-X,-W},{Y,W,X},{W,X,Y},{-W,-Y,-X}}

Permu=Permu/. {X-> XField,Y->YField,W-> WField}

(*The next two matrices containg all the permutations of the fields X,Y,Z with the corresponding and their corresponding sign. They are going to be used to compute the evaluation of each term that contributes to the CSW form.*)

Permu={{{X1,X2,X3},{Y1,Y2,Y3},{W1,W2,W3}},{{X1,X2,X3},{W1,W2,W3},{Y1,Y2,Y3}},{{Y1,Y2,Y3},{X1,X2,X3},{W1,W2,W3}},{{Y1,Y2,Y3},{W1,W2,W3},{X1,X2,X3}},{{W1,W2,W3},{X1,X2,X3},{Y1,Y2,Y3}},{{W1,W2,W3},{Y1,Y2,Y3},{X1,X2,X3}}};

SignPermu={1,-1,-1,1,1,-1};

(*At this point we define the components of the vectors X, Y, and W on which we will evaluate the CSW form. We also define the components of \dot\gamma(\tau).*)

Clear[NumIt, Con]

(*Compute the evaluation of every term of (Subscript[σ, 0])(ω)\wedge (Subscript[σ, 0])(ω) \wedge (Subscript[σ, 0])(ω)on all possible permutations of X,Y, W. The result is stored in the matrix Final, which is a matrix function of Co (the Sobolev parameter s) and NumIt (the number of iterations of the Hopf action). The matrix Final is a very complicated function of the variables and to simplify the computation of the integrals, we have to integrate each term first and then add with the corresponding sign*)

Final=Apply[ZeroMinusOneTerm1,Permu,{1}]+Apply[ZeroMinusOneTerm2,Permu,{1}]-Apply[ZeroMinusOneTerm3,Permu,{1}];

Final>>HopfCurvature

Clear[Con,NumIt];
FinalFunction[Theta_,Phi_,Psi_,tau_,Con_,NumIt_]=<< HopfCurvature

InteNox[Theta_,Phi_,Psi_,tau_,Con_,NumIt_]=FinalFunction[Theta,Phi,Psi,tau,Con,NumIt]

Clear[Integrand];
Integrand[Theta_,Phi_,Psi_,tau_,Co_,NumIt_]=Expand[Sum[FinalFunction[Theta,Phi,Psi,tau,Co,NumIt][[j]]*SignPermu[[j]],{j,1,6}]]*Sqrtdetmetric;

(*This is the beginning of the integration, the function InteNox[Theta_,Phi_,Psi_,tau_,Co_,NumIt_] contains the list of the six permutations. We made it dependent on Co and NumIt so by varying those parameters we can see the effect on the CSW form*)

(*Mathematica has trouble dealing with the values of the integrand at ϕ,ψ=0, π. To avoid these, we integrate close to these values by integrating the coordinates ϕ and ψ on the interval [0+ϵ, π-ϵ]. The vector IntegrandTable below contains the value of the integral of WCS with respect to the variables ϕ, ψ on (S^(3 ))and the loop variable τ for different values of ϵ. We do not integrate with respect to θ yet because the WCS integrand does not depend on θ.  There is no problem with this approximation because the integrand InteNox[θ, ϕ,  ψ, τ] is extremely small on [0,ϵ]  U  [π-ϵ, π]. *)

(* Computations for the CSW for epsilon=(10^(-2))*)

TotalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-2),Pi-10^(-2)},{Psi,0.+10^(-2),Pi-10^(-2)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[TotalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

(* Computations for the CSW for epsilon=(10^(-4))*)

TotalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-4),Pi-10^(-4)},{Psi,0.+10^(-4),Pi-10^(-4)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[TotalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

(* Computations for the CSW for epsilon=(10^(-6))*)

TotalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-6),Pi-10^(-6)},{Psi,0.+10^(-6),Pi-10^(-6)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[TotalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

(* Computations for the CSW for epsilon=(10^(-8))*)

TotalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-8),Pi-10^(-8)},{Psi,0.+10^(-8),Pi-10^(-8)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[TotalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

Conclusion:  We compute that the contribution from the term  (Subscript[σ, -1])(Ω)\wedge (Subscript[σ, 0])(ω) to the WCS integral over (S^3) is different for NumIt =  1, 2, even with different values of the Sobolev parameter s.

(2.2) Connection term contribution:  Contribution from the term (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(Ω).

Clear[SigmaZeroCurvature]

SigmaZeroCurvature[XF_,YF_]:=Table[Sum[Curvature[[a,e,p,q]]*XF[[q]]*YF[[p]],{p,1,dimension},{q,1,dimension}],{a,1,dimension},{e,1,dimension}]

SigmaZeroCurvature[XField,YField]// MatrixForm

SigmaZero>>FiLoZeroHopf

(*Computation of the -1 order  symbol for the connection (Subscript[σ, -1])(ω) from Proposition 3.3 in our paper.*)

Clear[Co,NumIt]

SigmaMinusTerm1[X_]:=Table[Sum[ DotGamma[[n]]*X[[i]]*(Co*(Sum[D[inversemetric[[a,f]],coord[[n]]]*D[metric[[f,e]],coord[[i]]],{f,1,dimension}]+ Sum[inversemetric[[a,f]]*D[metric[[f,e]],coord[[i]],coord[[n]]],{f,1,dimension}]-D[Christoffel[[a,n,e]],coord[[i]]]- Sum[inversemetric[[a,f]]*D[metric[[f,m]],coord[[i]]]*Christoffel[[m,n,e]],{f,1,dimension},{m,1, dimension}]+Sum[inversemetric[[k,f]]*D[metric[[e,f]],coord[[i]]]*Christoffel[[a,k,n]],{f,1,dimension},{k,1, dimension}])+D[Christoffel[[a,e,i]],coord[[n]]]-D[Christoffel[[a,n,i]],coord[[e]]]+Sum[Christoffel[[a,n,m]]*Christoffel[[m,e,i]],{m,1,dimension}]-Sum[Christoffel[[a,e,m]]*Christoffel[[m,n,i]],{m,1,dimension}] 
(* Expression (3.2) in the paper. *)
-(2*Co+1)*Sum[inversemetric[[l,a]]*metric[[t,p]]*Christoffel[[p,e,n]]*Christoffel[[t,l,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension}]+
(4*Co-3)*Sum[inversemetric[[l,a]]*metric[[t,e]]*D[Christoffel[[t,l,i]],coord[[n]]],{l,1,dimension},{t,1,dimension}]
+
Sum[inversemetric[[l,a]]*metric[[t,e]]*D[Christoffel[[t,n,i]],coord[[l]]],{l,1,dimension},{t,1,dimension}]+
Sum[inversemetric[[l,a]]*metric[[t,e]]*Christoffel[[t,l,p]]*Christoffel[[p,n,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension}]+
2*Co*(Sum[Christoffel[[a,n,p]]*inversemetric[[q,p]]*metric[[t,e]]*Christoffel[[t,q,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension},{q,1,dimension}]-Sum[inversemetric[[a,l]]*metric[[t,e]]*Christoffel[[p,l,n]]*Christoffel[[t,p,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension}]-Sum[inversemetric[[a,l]]*metric[[w,l]]*inversemetric[[p,q]]*metric[[t,e]]*Christoffel[[w,p,n]]*Christoffel[[t,q,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension},{q,1,dimension},{w,1,dimension}])
+(4*Co-2)*Sum[inversemetric[[l,a]]*metric[[t,e]]*Christoffel[[t,n,p]]*Christoffel[[p,l,i]],{l,1,dimension},{p,1,dimension}, {t,1,dimension}]),{i,1,dimension},{n, 1, dimension}],{a,1,dimension},{e, 1, dimension}];
SigmaMinusTerm2[X_]:=Table[Co*(Sum[inversemetric[[a,f]]* D[X[[i]],coord[[4]]]*D[metric[[f,e]],coord[[i]]],{i,1,dimension},{f,1, dimension}]-Sum[ D[X[[n]],coord[[4]]]*Christoffel[[a,n,e]],{n,1,dimension}])-(4*Co-1)*Sum[inversemetric[[l,a]]*metric[[t,e]]*Christoffel[[t, l,i]]* D[X[[i]],coord[[4]]],{l, 1,dimension},{t, 1,dimension},{i, 1,dimension}],{a,1,dimension},{e,1,dimension}]

(*Compute the evaluation of the term (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(Ω)on all possible permutations of X Y W. The result is stored in the matrix FinalFunction[Co, NumIt], which is a matrix function of Co (the Sobolev s parameter) and NumIt (the number of iterations of the Hopf action). The matrix FinalFunction[Co, NumIt] is a very complicated function of the variables and to simplify the computation of the integrals, we have to integrate each term first and then add with the corresponding sign*)

SigmaMinusZeroZero[XF_,YF_,ZF_]:=Tr[(SigmaMinusTerm1[XF]+SigmaMinusTerm2[XF]).SigmaZeroCurvature[YF,ZF]]

FinalFunction=Apply[SigmaMinusZeroZero,Permu,{1}]

FinalFunction>>FinalFunctionHopf2ndTerm

Clear[FinalFunction];
FinalFunction[Theta_,Phi_,Psi_,tau_,Co_,NumIt_]=<< FinalFunctionHopf2ndTerm

Clear[Integrand];
Integrand[Theta_,Phi_,Psi_,tau_,Co_,NumIt_]=Expand[Sum[FinalFunction[Theta,Phi,Psi,tau,Co,NumIt][[j]]*SignPermu[[j]],{j,1,6}]]*Sqrtdetmetric;

(* Computations for the CSW for epsilon=(10^(-2))*)

TotalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-2),Pi-10^(-2)},{Psi,0.+10^(-2),Pi-10^(-2)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[TotalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

(* Computations for the CSW for epsilon=(10^(-4))*)

TotalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-4),Pi-10^(-4)},{Psi,0.+10^(-4),Pi-10^(-4)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[TotalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

(* Computations for the CSW for epsilon=(10^(-6))*)

TotalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-6),Pi-10^(-6)},{Psi,0.+10^(-6),Pi-10^(-6)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[TotalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

Conclusion:  We compute that the contribution from the term  (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(Ω) to the WCS integral over (S^3) is different for NumIt =  1, 2, for different values of the Sobolev parameter s.

(2.3) Connection term contribution:  Contribution from the term (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(ω) \wedge (Subscript[σ, 0])(ω)

Dot1=NumIt*Cos[NumIt*tau] Sin[Phi] Sin[Psi];
Dot2=NumIt*Cos[Psi] Cos[NumIt*tau] Sin[Phi];
Dot3=NumIt*(-((Cos[Phi])^2) Cos[Psi] Sin[Psi] Sin[NumIt*tau]-Cos[Psi] Sin[Psi] (Cos[NumIt*tau]+((Sin[Phi])^2) Sin[NumIt*tau])+Cos[Phi] (-((Cos[Psi])^2) Cos[NumIt*tau]+((Sin[Psi])^2) Sin[NumIt*tau]));
X1=Cos[NumIt*tau] Sin[Phi] Sin[Psi];X2=-Cos[Phi] Sin[Phi] Sin[Psi] Sin[NumIt*tau];X3=-Cos[Psi] ((Sin[Phi])^2) Sin[Psi] Sin[NumIt*tau];
Y1=Cos[Phi] Sin[Psi] Sin[NumIt*tau];Y2=Cos[NumIt*tau] Sin[Psi];Y3=Cos[NumIt*tau] Sin[Phi] ((Sin[Psi])^2);
W1=Cos[Psi] Sin[Phi] Sin[NumIt*tau];W2=-Sin[Psi] Sin[NumIt*tau];W3=Cos[Psi] Cot[Phi] (-Cos[NumIt*tau]+Sin[NumIt*tau])+Csc[Phi] (Cos[Psi] Cos[NumIt*tau] Cot[Psi]+Sin[Psi] Sin[NumIt*tau]);

Permu={{{X1,X2,X3},{Y1,Y2,Y3},{W1,W2,W3}},{{X1,X2,X3},{W1,W2,W3},{Y1,Y2,Y3}},{{Y1,Y2,Y3},{X1,X2,X3},{W1,W2,W3}},{{Y1,Y2,Y3},{W1,W2,W3},{X1,X2,X3}},{{W1,W2,W3},{X1,X2,X3},{Y1,Y2,Y3}},{{W1,W2,W3},{Y1,Y2,Y3},{X1,X2,X3}}};
SignPermu={1,-1,-1,1,1,-1};

Clear[SigmaZero]

SigmaZero[XF_]:=Table[Sum[Christoffel[[i,j,q]]*XF[[q]],{q,1,dimension}],{i,1,dimension},{j,1,dimension}]

SigmaZero[XField]// MatrixForm

SigmaZero>>FiLoZeroHopf

(*Computation of the -1 order  symbol for the connection (Subscript[σ, -1])(ω) from Proposition 3.3 in our paper.*)

Clear[Co,NumIt]

SigmaMinusTerm1[X_]:=Table[Sum[ DotGamma[[n]]*X[[i]]*(Co*(Sum[D[inversemetric[[a,f]],coord[[n]]]*D[metric[[f,e]],coord[[i]]],{f,1,dimension}]+ Sum[inversemetric[[a,f]]*D[metric[[f,e]],coord[[i]],coord[[n]]],{f,1,dimension}]-D[Christoffel[[a,n,e]],coord[[i]]]- Sum[inversemetric[[a,f]]*D[metric[[f,m]],coord[[i]]]*Christoffel[[m,n,e]],{f,1,dimension},{m,1, dimension}]+Sum[inversemetric[[k,f]]*D[metric[[e,f]],coord[[i]]]*Christoffel[[a,k,n]],{f,1,dimension},{k,1, dimension}])+D[Christoffel[[a,e,i]],coord[[n]]]-D[Christoffel[[a,n,i]],coord[[e]]]+Sum[Christoffel[[a,n,m]]*Christoffel[[m,e,i]],{m,1,dimension}]-Sum[Christoffel[[a,e,m]]*Christoffel[[m,n,i]],{m,1,dimension}] 
(* Expression (3.2) in the paper. *)
-(2*Co+1)*Sum[inversemetric[[l,a]]*metric[[t,p]]*Christoffel[[p,e,n]]*Christoffel[[t,l,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension}]+
(4*Co-3)*Sum[inversemetric[[l,a]]*metric[[t,e]]*D[Christoffel[[t,l,i]],coord[[n]]],{l,1,dimension},{t,1,dimension}]
+
Sum[inversemetric[[l,a]]*metric[[t,e]]*D[Christoffel[[t,n,i]],coord[[l]]],{l,1,dimension},{t,1,dimension}]+
Sum[inversemetric[[l,a]]*metric[[t,e]]*Christoffel[[t,l,p]]*Christoffel[[p,n,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension}]+
2*Co*(Sum[Christoffel[[a,n,p]]*inversemetric[[q,p]]*metric[[t,e]]*Christoffel[[t,q,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension},{q,1,dimension}]-Sum[inversemetric[[a,l]]*metric[[t,e]]*Christoffel[[p,l,n]]*Christoffel[[t,p,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension}]-Sum[inversemetric[[a,l]]*metric[[w,l]]*inversemetric[[p,q]]*metric[[t,e]]*Christoffel[[w,p,n]]*Christoffel[[t,q,i]],{l,1,dimension},{t,1,dimension},{p,1,dimension},{q,1,dimension},{w,1,dimension}])
+(4*Co-2)*Sum[inversemetric[[l,a]]*metric[[t,e]]*Christoffel[[t,n,p]]*Christoffel[[p,l,i]],{l,1,dimension},{p,1,dimension}, {t,1,dimension}]),{i,1,dimension},{n, 1, dimension}],{a,1,dimension},{e, 1, dimension}];
SigmaMinusTerm2[X_]:=Table[Co*(Sum[inversemetric[[a,f]]* D[X[[i]],coord[[4]]]*D[metric[[f,e]],coord[[i]]],{i,1,dimension},{f,1, dimension}]-Sum[ D[X[[n]],coord[[4]]]*Christoffel[[a,n,e]],{n,1,dimension}])-(4*Co-1)*Sum[inversemetric[[l,a]]*metric[[t,e]]*Christoffel[[t, l,i]]* D[X[[i]],coord[[4]]],{l, 1,dimension},{t, 1,dimension},{i, 1,dimension}],{a,1,dimension},{e,1,dimension}]

(*Compute the evaluation of every term of (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(ω) \wedge (Subscript[σ, 0])(ω)on all possible permutations of X,Y, W. The result is stored in the matrix FinalFunction[Co, NumIt], which is a matrix function of Co (the s parameter) and NumIt (the number of iterations of the Hopf action). The matrix FinalFunction[Co, NumIt] is a very complicated function of the variables and to simplify the computation of the integrals, we have to integrate each term first and then add with the corresponding sign*)

SigmaMinusZeroZero[XF_,YF_,ZF_]:=Tr[(SigmaMinusTerm1[XF]+SigmaMinusTerm2[XF]).SigmaZero[YF].SigmaZero[ZF]]

FinalFunction=Apply[SigmaMinusZeroZero,Permu,{1}];

FinalFunction>> FinalFunctionHopfTwo

Clear[FinalFunction]

FinalFunction[Theta_,Phi_,Psi_,tau_,Co_,NumIt_]=<< FinalFunctionHopfTwo

Clear[Integrand];
Integrand[Theta_,Phi_,Psi_,tau_,Co_,NumIt_]=Expand[Sum[FinalFunction[Theta,Phi,Psi,tau,Co,NumIt][[j]]*SignPermu[[j]],{j,1,6}]]*Sqrtdetmetric;

Symbolic computations for epsilon=(10^(-2)).

FinalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-2),Pi-10^(-2)},{Psi,0.+10^(-2),Pi-10^(-2)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[FinalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

Symbolic computations for epsilon=(10^(-4)).

FinalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-4),Pi-10^(-4)},{Psi,0.+10^(-4),Pi-10^(-4)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[FinalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

Symbolic computations for epsilon=(10^(-6)).

FinalComputationTables=Table[NIntegrate[Integrand[Theta,Phi,Psi,tau,s,i],{Phi,0.+10^(-6),Pi-10^(-6)},{Psi,0.+10^(-6),Pi-10^(-6)},{tau,0.,2*Pi},Method->{"GlobalAdaptive"},MaxRecursion->20],{s,1,2},{i,1,2}]

TableForm[FinalComputationTables,TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

Conclusion:  We compute that the contribution from the term  (Subscript[σ, -1])(ω)\wedge (Subscript[σ, 0])(ω) \wedge (Subscript[σ, 0])(ω) to the WCS integral over (S^3) is different for NumIt =  1, 2.

(3) Conclusions

Adding the contributions of the three terms (2.1), (2.2), (2.3), with the corresponding factors as in (7.6) in our paper and  accounting for different variations of the Sobolev parameter s, we find that the iterates n=1,2 of the (S^1) action define nonhomologous classes in (Subscript[H, 3])((LS^3)). We show this for one value of the integration parameter ϵ=(10^(-2)), (10^(-4)). Notice that decreasing the value of ϵ does not change significantly the expected behavior of the CSW form. In particular, modulo numerical accuracy, the CSW is multiplicative in the iterates of the (S^1)action, as it must be.

Computation for ϵ=(10^(-2)). An overall factor of -1 is not included in the computations. This factor comes from the product of (i) -(1/(8(π^3)))in the definition of the WCS form, (ii) 2π from the integration over θ (as the integrand is independent of θ), (iii) 4π from the integration over ξ (as the integrand is independent of ξ).

TableForm[{{-1.0717562052326846`,-2.1434551754980116`},{-0.8329032620694847`,-1.6658026251894433`}}+{{-2.8584084939975556`,-5.71681696018721`},{-5.938966070928109`,-11.877933709907747`}}-1/6{{-0.2818850026479721`,-0.5637405362518368`},{-0.5350778401331272`,-1.070167410005634`}},TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

Computation for ϵ=(10^(-4)). An overall factor of -(1/(8(π^3))) is not included in the computations. The final contribution is taken from expression (7.6) in the paper.

TableForm[{{-1.0717270076756098`,-2.1433736007302735`},{-0.8329032797855261`,-1.6658064597145823`}}+{{-2.858408474361262`,-5.716816998171442`},{-5.938967002438893`,-11.87790255651215`}}-1/6{{-0.31852375178618836`,-0.6370475983831861`},{-0.5961745863100261`,-1.1922959585853166`}},TableHeadings->{{"s=1","s=2"},{"NumInt=1","NumInt=2"}}]

Conclusion 1:  We compute that the total contribution from all terms in the WCS integral over the action cycles in (LS^3)associated to the iterates of the Hopf action  are different for NumIt =  1, 2.  Therefore these iterates of the Hopf action define nonhomologous classes in (Subscript[H, 3])(L (S^3)).

Conclusion 2:   The WCS integral over the action cycles in (LS^3)associated to the Hopf and rotational actions are different for NumIt=1,2, and Sobolev parameter s =1.  

(See the notebook CompuationsRotations.nb. ) Therefore these actions define nonhomologous classes in(Subscript[H, 3])(L (S^3)).